let

  name = "nix-shell.canory";

  pkgs = import (builtins.fetchTarball {
    url = "https://releases.nixos.org/nixos/22.05/nixos-22.05.998.d17a56d90ec/nixexprs.tar.xz";
    sha256 = "084dzb7fmchfhhflrgprjjv7qz3j7vxw3d01f82q8p4g1x7hzn36";
  }) { };

  validatornu = pkgs.callPackage (pkgs.fetchurl {
    url = "https://raw.githubusercontent.com/tdro/dotfiles/032efcf7f4b1c7304ce5f3f64f64c175ba59eb6d/.config/nixpkgs/packages/validatornu/default.nix";
    sha256 = "1ify40x9547z04hcibk76m45d02xg3dlvwc57n8vxcbax82yb9pj";
  }) { };

  mkShellPure = pkgs.callPackage (pkgs.fetchurl {
    url = "https://raw.githubusercontent.com/tdro/dotfiles/b710281b132056105709c03dda1899a6afc68a93/.config/nixpkgs/helpers/mkShellPure.nix";
    sha256 = "1ciwifsx2hrp0ymm077zfb5q8ravrk545bda1q249y2spw9np4ms";
  }) { };

  check-jsonschema = pkgs.callPackage (pkgs.fetchurl {
    url = "https://raw.githubusercontent.com/NixOS/nixpkgs/82e9e32436d5886102f1e5f7c17aed8475504991/pkgs/development/tools/check-jsonschema/default.nix";
    sha256 = "sha256-PImZIMGa6+DE2f4tXiPS8ck7enThJvi9uiyxHvXm9WQ";
  }) { };

  hugo = pkgs.callPackage ({ lib, buildGo118Module, fetchgit, installShellFiles }:

    buildGo118Module rec {
      pname = "hugo";
      version = "0.101.0";

      src = fetchgit {
        rev = "v${version}";
        url = "https://github.com/gohugoio/hugo.git";
        sha256 = "sha256-Fodcefp8xdSV2tt6ZYaKdcLqVe2upEngQr6M+wV5wnw=";
      };

      doCheck = false;
      proxyVendor = true;
      vendorSha256 = "sha256-rReqDOhBKZO1qa3C4jmewGgmhLvvOYyxwWqsdm+6DzM=";

      tags = [ "extended" ];
      subPackages = [ "." ];
      nativeBuildInputs = [ installShellFiles ];

      postInstall = ''
        $out/bin/hugo gen man
        installManPage man/*
      '';

      meta = {
        license = lib.licenses.asl20;
        homepage = "https://gohugo.io";
        description = "A fast and modern static website engine";
        maintainers = with lib.maintainers; [ schneefux Br1ght0ne Frostman ];
      };
  }) { };

in mkShellPure {

  inherit hugo;

  packages = [
    check-jsonschema
    hugo
    validatornu
    pkgs.busybox
    pkgs.deno
    pkgs.entr
    pkgs.git
    pkgs.gnumake
    pkgs.jing
    pkgs.libxml2
    pkgs.libxslt
    pkgs.php
    pkgs.subversion
    pkgs.yj
  ];

  shellHook = ''
    export PS1='\h (${name}) \W \$ '
  '';
}